added new queue t_list_queue, implemented as linked list

sim/QueueP.vhd

@@ -1,7 +1,3 @@
--- simple queue protected type
--- inspired by noasic article http://noasic.com/blog/a-simple-fifo-using-vhdl-protected-types/
-
-
 library ieee;
   use ieee.std_logic_1164.all;
 
@@ -10,6 +6,8 @@ library ieee;
 package QueueP is
 
 
+  -- simple queue protected type
+  -- inspired by noasic article http://noasic.com/blog/a-simple-fifo-using-vhdl-protected-types/
   type t_simple_queue is protected
 
     procedure push (data : in  std_logic_vector);
@@ -22,6 +20,19 @@ package QueueP is
   end protected t_simple_queue;
 
 
+  -- linked list queue
+  type t_list_queue is protected
+
+    procedure push (data : in  std_logic_vector);
+    procedure pop  (data : out std_logic_vector);
+    impure function is_empty return boolean;
+    impure function is_full  return boolean;
+    impure function fillstate return natural;
+    impure function freeslots return natural;
+
+  end protected t_list_queue;
+
+
 end package QueueP;
 
 
@@ -90,4 +101,79 @@ package body QueueP is
   end protected body t_simple_queue;
 
 
-end package body QueueP;
+  type t_list_queue is protected body
+
+    constant C_QUEUE_DEPTH : natural := 64;
+    constant C_QUEUE_WIDTH : natural := 64;
+
+    type t_entry;
+    type t_entry_ptr is access t_entry;
+
+    type t_entry is record
+      data       : std_logic_vector(C_QUEUE_WIDTH-1 downto 0);
+      last_entry : t_entry_ptr;
+      next_entry : t_entry_ptr;
+    end record t_entry;
+
+    variable v_head : t_entry_ptr;
+    variable v_tail : t_entry_ptr;
+    variable v_count : natural range 0 to C_QUEUE_DEPTH := 0;
+
+    -- write one entry into queue
+    procedure push (data : in  std_logic_vector) is
+    begin
+      assert not(is_full)
+        report "push into full queue -> discarded"
+        severity failure;
+      if(v_head /= null) then
+        v_head := new t_entry'(data, v_head, null);
+        v_head.last_entry.next_entry := v_head;
+      else
+        v_head := new t_entry'(data, null, null);
+        v_tail := v_head;
+      end if;
+      v_count := v_count + 1;
+    end procedure push;
+
+    -- read one entry from queue
+    procedure pop  (data : out std_logic_vector) is
+      variable v_entry : t_entry_ptr;
+    begin
+      assert not(is_empty)
+        report "pop from empty queue -> discarded"
+        severity failure;
+      data := v_tail.data;
+      v_entry := v_tail;
+      v_tail := v_tail.next_entry;
+      deallocate(v_entry);
+      v_count := v_count - 1;
+    end procedure pop;
+
+    -- returns true if queue is empty, false otherwise
+    impure function is_empty return boolean is
+    begin
+      return v_tail = null;
+    end function is_empty;
+
+    -- returns true if queue is full, false otherwise
+    impure function is_full return boolean is
+    begin
+      return v_count = C_QUEUE_DEPTH;
+    end function is_full;
+
+    -- returns number of filled slots in queue
+    impure function fillstate return natural is
+    begin
+      return v_count;
+    end function fillstate;
+
+    -- returns number of free slots in queue
+    impure function freeslots return natural is
+    begin
+      return C_QUEUE_DEPTH - v_count;
+    end function freeslots;
+
+  end protected body t_list_queue;
+
+
+end package body QueueP;

test/QueueT.vhd

@@ -12,32 +12,33 @@ end entity QueueT;
 architecture sim of QueueT is
 
 
-  shared variable sv_queue : work.QueueP.t_simple_queue;
+  shared variable sv_simple_queue : work.QueueP.t_simple_queue;
+  shared variable sv_list_queue   : work.QueueP.t_list_queue;
 
 
 begin
 
 
-  QueueTestP : process is
+  SimpleQueueTestP : process is
     variable v_data  : std_logic_vector(63 downto 0);
     variable v_count : natural := 0;
   begin
     -- check initial emptiness
-    assert sv_queue.is_empty
+    assert sv_simple_queue.is_empty
       report "ERROR: queue should be empty!"
       severity failure;
     for i in 0 to 63 loop
-      sv_queue.push(std_logic_vector(to_unsigned(v_count, 64)));
+      sv_simple_queue.push(std_logic_vector(to_unsigned(v_count, 64)));
       v_count := v_count + 1;
     end loop;
     -- check that it's full
-    assert sv_queue.is_full
+    assert sv_simple_queue.is_full
       report "ERROR: queue should be full!"
       severity failure;
     -- empty the queue
     v_count := 0;
     for i in 0 to 63 loop
-      sv_queue.pop(v_data);
+      sv_simple_queue.pop(v_data);
       assert v_data = std_logic_vector(to_unsigned(v_count, 64))
         report "ERROR: read data should be " & integer'image(v_count) &
                " instead of " & integer'image(to_integer(unsigned(v_data)))
@@ -45,12 +46,47 @@ begin
       v_count := v_count + 1;
     end loop;
     -- check emptiness
-    assert sv_queue.is_empty
+    assert sv_simple_queue.is_empty
       report "ERROR: queue should be empty!"
       severity failure;
-    report "INFO: Test finished successfully";
+    report "INFO: t_simple_queue test finished successfully";
     wait;
-  end process QueueTestP;
+  end process SimpleQueueTestP;
+
+
+  ListQueueTestP : process is
+    variable v_data  : std_logic_vector(63 downto 0);
+    variable v_count : natural := 0;
+  begin
+    -- check initial emptiness
+    assert sv_list_queue.is_empty
+      report "ERROR: queue should be empty!"
+      severity failure;
+    for i in 0 to 63 loop
+      sv_list_queue.push(std_logic_vector(to_unsigned(v_count, 64)));
+      v_count := v_count + 1;
+    end loop;
+    -- check that it's full
+    assert sv_list_queue.is_full
+      report "ERROR: queue should be full!"
+      severity failure;
+    -- empty the queue
+    v_count := 0;
+    for i in 0 to 63 loop
+      sv_list_queue.pop(v_data);
+      assert v_data = std_logic_vector(to_unsigned(v_count, 64))
+        report "ERROR: read data should be " & integer'image(v_count) &
+               " instead of " & integer'image(to_integer(unsigned(v_data)))
+        severity failure;
+      v_count := v_count + 1;
+    end loop;
+    -- check emptiness
+    assert sv_list_queue.is_empty
+      report "ERROR: queue should be empty!"
+      severity failure;
+    report "INFO: t_list_queue test finished successfully";
+    wait;
+  end process ListQueueTestP;
 
 
 end architecture sim;